Vers 3.03 asking in Excel to save after 3rd worksheet

[MJEPO]

HI, we are using Amyuni PDF Converter 3.03 currently and faced with the following problem:

When doing a print in MS Excel 2003 for the entire workbook (Overwrite Option is set to Append to existing file), i will be asked to save the file after every 3rd sheet in excel
Is there a way to prevent this so that the entire workbook with for e.g. 8 sheets will be printed to PDF without asking me to save after every 3rd sheet? Thx

[Devteam]

Microsoft Excel sometimes splits a printout into multiple print jobs which prompts the PDF printer to ask for a file name for every print job.

One solution around this is to create a VBA macro in Excel to print the document rather than going through File-->Print. Here a sample Macro:

Code: Select all

Sub PrintToPDF()

    Dim PdfFileName As String
    Dim PrinterName As String
    
    ' This should be modified to reflect the real PDF file name
    PrinterName = "Amyuni PDF Converter"

    ' Prompt for the output PDF
    PdfFileName = Application.GetSaveAsFilename(FileFilter:="PDF files (*.pdf),*.pdf", Title:="Enter the destination file name")
    
    ' Delete the existing PDF if any (skip this step if you want to append to an existing PDF)
    Set fs = CreateObject("Scripting.FileSystemObject")
    If fs.FileExists(PdfFileName) Then
        fs.DeleteFile PdfFileName
    End If
    Set fs = Nothing

    Dim cdi As Object
    ' Create the PDF Converter ActiveX, the version number depends on the version installed
    Set cdi = CreateObject("CDIntfEx.CDIntfEx") ' CDIntfEx.CDIntfEx.4.5 for version 4.5
    cdi.DriverInit PrinterName                  ' Attach to the printer
    cdi.FileNameOptions = 1 + 2 + 4             ' NoPrompt + UseFileName + Append
    cdi.DefaultFileName = PdfFileName           ' Set the output file name
    
    Application.ActiveWorkbook.PrintOut ActivePrinter:=PrinterName
                                                ' Print active Workbook
    
    cdi.FileNameOptions = 0                     ' Reset printer parameters in order not to overwrite existing PDFs
    cdi.DefaultFileName = ""
    
    Set cdi = Nothing
    
End Sub